EEC210 Common Source Amp with Complementary Load - Problem Set #4, Problem 3
*
* Power Supply
*
vdd vdd 0  vdd
.param vdd=3
*
* Input
*
vi  1   0  vidc    ac 1
.param vidc=893.3m
*The dc input is adjusted by trial and error so that the
*dc output voltage is about 1 Volt.
*
* Test Circuit
*
m1  out 1  0   0   cmosn l=1u w=100u
m2  out 3  vdd vdd cmosp l=1u w=100u
m3  3   3  vdd vdd cmosp l=1u w=100u
ir  3   0  ibias
.param  ibias=1m
*
* Models
*
.model cmosn nmos level=1 lambda=0.024 vto=0.6  kp=194u ld=0.09u
.model cmosp pmos level=1 lambda=0.049 vto=-0.6 kp=65u  ld=0.09u
*
* Don't print the model parameters
*
.options nomod
*
* Analysis
*
.op 
.tf v(out) vi
*.dc vi 0.5 0.902 0.001
*.print dc v(out) lx7(m1) par('1./(lx8(m1)+lx8(m2))') par('lx7(m1)/(lx8(m1)+lx8(m2))')
*lx7(m1) = gm1, lx8(m1) = 1/ro1, lx8(m2) = 1/ro2
*lx7(m1)/(lx8(m1)+lx8(m2)) = gm1 * (ro1 || ro2)

.alter
.param vidc=693.4m
.param  ibias=100u

.alter
.param  ibias=10u
.param vidc=629.6m

.alter
.param  ibias=1u
.param vidc=609.38m

.alter "weak inversion"
.param  ibias=1m
.param vidc=901.0m

* To include weak inversion effects, must change to at least
* the level 2 model.

.model cmosn nmos level=2 vto=0.6 kp=194u ld=0.09u
+ tox=8E-09 lambda=0.024 nfs=1.35e12 nsub=5e15
.model cmosp pmos level=2 vto=-0.6 kp=65u ld=0.09u
+ tox=8E-09 lambda=0.049 nfs=1.35e12 nsub=4e16

* In the hspice model, id is proportional to exp[(VGS - Vt)/fast]
* In Chapter 1, id is proportional to exp[(VGS - Vt)/(nVT)]
* Therefore, fast must equal nVT (which is n thermal voltages)
* From page 7-19 of the hspice manual,
* fast is about equal to VT(1 + q NFS/Cox)
* Therefore n = 1 + q NFS/Cox
* Solving for NFS gives NFS = (n-1)Cox/q
* Cox should be in Farads/cm^2 and q is in Coulombs
* For example, if n=1.5, Cox = 4.32e-7 (for tox=80 Angstroms)
* NFS = 0.5*4.32e-7/1.6e-19 = 1.35e12

.alter
.param  ibias=100u
.param vidc=696.4m

.alter
.param  ibias=10u
.param vidc=618.4m

.alter
.param  ibias=1u
.param vidc=526.4m

.end